Vracím se ještě k tomuto tématu: viewtopic.php?f=35&t=55191&start=0
V Excelu 2007 již není panel kreslení, a zjistil jsem, že jej lze vyvolat jen označením grafického prvku. Pokud však označím komentář, tak to nefunguje.
Má někdo radu jak tento návod aplikovat na Excel 2007? (Zkoušel jsem všelicos, ale nepovedlo se mi změnit ani tvar komentáře, ani vložit obrázek - vždy se tvar nebo obrázek vloží mimo komentář)
Obrázek do buňky v Excelu (doplnění)
-
- Level 4
- Příspěvky: 1142
- Registrován: srpen 08
- Pohlaví:
- Stav:
Offline
Re: Obrázek do buňky v Excelu (doplnění)
Pokud mas na mysli vlozeni obrazku do komentare v Ex2007, postupuj takto:
vybrat bunku s komentarem, v pasu karet vybrat upavit komentar, LT mysi klik na srafovane ohraniceni komentare, zmeni se na teckovane (zmena editace textove casti na editaci formatu), PT mysi klik na ohraniceni, otevre se nabidka, vybrat Format komentare, zalozka Barvy a cary, v casti Vypln klik na rozbalovaci nabidku Barva, klik na vzhled vyplne, vybrat zalozku Obrazek a klik na Vybrat obrazek z adresare, Vlozit,..cili postup podobny jak je uvedeno v http://www.dataspectrum.cz/pages/glossa ... entar2.htm - cast vlozeni obrazku.
PS.: popsany postup je identicky s postupem pro nizsi verze Excelu az na pas karet.
vybrat bunku s komentarem, v pasu karet vybrat upavit komentar, LT mysi klik na srafovane ohraniceni komentare, zmeni se na teckovane (zmena editace textove casti na editaci formatu), PT mysi klik na ohraniceni, otevre se nabidka, vybrat Format komentare, zalozka Barvy a cary, v casti Vypln klik na rozbalovaci nabidku Barva, klik na vzhled vyplne, vybrat zalozku Obrazek a klik na Vybrat obrazek z adresare, Vlozit,..cili postup podobny jak je uvedeno v http://www.dataspectrum.cz/pages/glossa ... entar2.htm - cast vlozeni obrazku.
PS.: popsany postup je identicky s postupem pro nizsi verze Excelu az na pas karet.
Re: Obrázek do buňky v Excelu (doplnění)
Dík za radu. Tento postup mě nenapadnul. Ten odkaz už je neplatný. Ještě by mě zajímalo, jakým způsobem lze změnit tvar komentáře. Nikde jsem ve Formátu komentáře nenašel tvary aby se daly měnit, tak jak to je uvedeno v odkazované diskuzi.
-
- Level 4
- Příspěvky: 1142
- Registrován: srpen 08
- Pohlaví:
- Stav:
Offline
Re: Obrázek do buňky v Excelu (doplnění)
Odkaz byl z nejakeho duvodu zkracen, takze vlozeny odkaz je samozrejme neplatny. Zde je platny odkaz: http://www.dataspectrum.cz/pages/glossa ... entar2.htm
Zmena tvaru komentare v Ex 2007 - nevim, mozna nekdo jiny.
PS: Pod VBA lze i v Excelu 2007 zmenit tvar komentare, overeno:
Zmena tvaru komentare v Ex 2007 - nevim, mozna nekdo jiny.
PS: Pod VBA lze i v Excelu 2007 zmenit tvar komentare, overeno:
Kód: Vybrat vše
Option Explicit
Sub VlozKomentarTvar() ' zmena zakladniho tvaru na vybrany (napr.: oblak)
Dim cell As Range
Set cell = Worksheets("list2").Range("i6")
With cell
.ClearComments ' odstrani pripadny komentar
.AddComment
With .Comment
.Visible = True
.Shape.TextFrame.AutoSize = True
.Shape.Select True
With Selection.ShapeRange
.AutoShapeType = msoShapeCloudCallout ' oblak
.Adjustments.Item(1) = -0.0938 ' uprava navazani oblaku na znacku komentare
.Adjustments.Item(2) = 0.1757
End With
.Text Text:="123456" & Chr(10) & "fdfgdfgdfgdf" & Chr(10) _
& "abcdefghijklmnopqrstuvwxyz" & Chr(10) _
& " sdfkjslfkd" ' text komentare
.Shape.Select False
.Visible = False
End With
End With
End Sub
Re: Obrázek do buňky v Excelu (doplnění)
Dík za zprávu a makro, uložím a někdy použiji. Ještě mám dotaz k tomu vkládání gotek. To je funkce kterou potřebuji, to znamená když myší najedu na buňku, tak se zobrazí obrázek. Akorát je to trochu pracné ty obrázky vkládat do komentáře. Tak mám dotaz, jestli toto je jediná možnost, jak tuto funkci vExcelu zajistit, nebo to lze udělat i jinak?
-
- Level 4
- Příspěvky: 1142
- Registrován: srpen 08
- Pohlaví:
- Stav:
Offline
Re: Obrázek do buňky v Excelu (doplnění)
Tak samozrejme muzes obrazky vlozit do bunek, ala mas bud mrnave obrazky nebo velke bunky nebo v bunce hypertextovy odkaz na obrazek.
Vlozit sadu obrazku do komentaru muzes pouzitim procedury VBA.
Napr.:
obrazky z adresare, v bunce je napr nazev obrazku; vlozeni zajisti udalostni procedura (zaklad bez osetreni nekorektnich stavu nize, cestu a priponu si uprav):
A jsou i jine moznosti.
Vlozit sadu obrazku do komentaru muzes pouzitim procedury VBA.
Napr.:
obrazky z adresare, v bunce je napr nazev obrazku; vlozeni zajisti udalostni procedura (zaklad bez osetreni nekorektnich stavu nize, cestu a priponu si uprav):
Kód: Vybrat vše
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmnt As Excel.Comment
With Target
'odstrani pripadny komentar a vlozi novy
.ClearComments
Set Cmnt = .AddComment
'vlozi obrazek podle nazvu v bunce
'a formatuje komentar - rozmery
With Cmnt
.Shape.Fill.UserPicture "D:\Data\Excel\Obrazky\" & .Parent.Value & ".bmp"
.Shape.Height = 150
.Shape.Width = 150
.Visible = True ' trvale zobrazit, jinak False
End With
End With
End Sub
A jsou i jine moznosti.
Re: Obrázek do buňky v Excelu (doplnění)
To je super. Ještě jenom takové doplnění. Makro se spouští po každém stisku Enter, takže jestli by bylo možné nějak jednoduše ošetřit stav, kdy není příslušný soubor nalezen? (Což je vždy když jenom edituji buňku a nechci tam vkládat obrázek) Představoval bych si to tak, že se makro ukončí.
-
- Level 4
- Příspěvky: 1142
- Registrován: srpen 08
- Pohlaví:
- Stav:
Offline
Re: Obrázek do buňky v Excelu (doplnění)
To atari:
Uvadel jsem, ze je to bez osetreni nekorektnich stavu. Protoze se na poradne vyskytujes jiz od rijna 2008 a podal jsi cca 40 dotazu tykajicich se casto VBA, mel jsem zato, ze ti jiz uplatnenim ziskanych poznatku nebude cinit problem proceduru patricne doplnit. Nejspise jsem se zmylil.
Takze zde je doplnena procedura ( je to jeden z nekolika moznych postupu vlozeni obrazku do komentare, zde vlozeni nazvu obrazku do bunky, cesta a rozsireni je zadano v procedure, takze upravit dle potreby); vloz v editoru VBA do modulu prislusneho listu:
Uvadel jsem, ze je to bez osetreni nekorektnich stavu. Protoze se na poradne vyskytujes jiz od rijna 2008 a podal jsi cca 40 dotazu tykajicich se casto VBA, mel jsem zato, ze ti jiz uplatnenim ziskanych poznatku nebude cinit problem proceduru patricne doplnit. Nejspise jsem se zmylil.
Takze zde je doplnena procedura ( je to jeden z nekolika moznych postupu vlozeni obrazku do komentare, zde vlozeni nazvu obrazku do bunky, cesta a rozsireni je zadano v procedure, takze upravit dle potreby); vloz v editoru VBA do modulu prislusneho listu:
Kód: Vybrat vše
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmnt As Excel.Comment, DiskPath As String, Extsn As String
' je zmena v pozadovane oblasti bunek
If Intersect(Target, Me.Range("c4:c7")) Is Nothing Then Exit Sub
' redukce na jednu bunku (napr. pri mazani vice bunek)
Set Target = Target.Resize(1, 1)
' disk a cesta, rozsireni
DiskPath = "D:\Data\Excel\"
Extsn = ".bmp"
With Target
'odstrani pripadny komentar a vlozi novy
.ClearComments
' bunka je prazdna
If Target.Value = vbNullString Then Exit Sub
Set Cmnt = .AddComment
'vlozi obrazek podle nazvu v bunce
'a formatuje komentar
With Cmnt
On Error Resume Next
.Shape.Fill.UserPicture DiskPath & .Parent.Value & Extsn
' osetreni chyby pri odkazu na obrazek
If err.Number <> 0 Then
'*vyber si moznost odstranenim a pridanim apostrofu k prislusnemu radku, zde prvni moznost*
' bud bez vlozeni prazdneho komentare
Target.ClearComments: GoTo ErrHandler
' nebo vlozeny komentar se sdelenim
' .Text Text:="Obrazek nebyl nalezen"
'**********************************
End If
On Error GoTo 0
' nastavit rozmery komentare
.Shape.Height = 150 ' vyska
.Shape.Width = 150 ' sirka
' zobrazeni komentare pouze pri najeti kurzoru na bunku = False nebo trvale = True
.Visible = False ' True
End With
End With
ErrHandler:
Set Cmnt = Nothing
End Sub
Re: Obrázek do buňky v Excelu (doplnění)
Děkuji za ochotu. Ostatní jsem si doupravil a vše funguje. Můj původní záměr byl, aby něco takového fungovalo v aplikaci OneNote, že bude malý obrázek a najetím myši (nebo klikem) se to zvětší. Jenže OneNote toto neumí. A hypertextový odkaz je nevyhovující, takže jsem uvítal tuto možnost přes komentář v Excelu. To mě dříve nenapadlo.
(Také bych rád uměl více s VBA, ale jsem odchovanec předrevolučního školství, kde nás tyto věci neučili. Koupil jsem si knihu "John Walkenbach - programování ve VBA." Některým věcem ovšem v té knize nerozumím. Jsem totiž samouk, a Excelu se věnuji občas po večerech, spíše to je takové hobby, že občas něco vymyslím pro sebe a kamarády (kteří ani nevědí že VBA existuje - u ních jsem King.... ), takže se případně omlouvám za to, že něco déle chápu. Chybové stavy a podobné jsem ještě neprostudoval, ještě jsem se k tomu nedostal, spíše jsem psal kod tak, aby nemohli nastat pokud to bylo možné.)
(Také bych rád uměl více s VBA, ale jsem odchovanec předrevolučního školství, kde nás tyto věci neučili. Koupil jsem si knihu "John Walkenbach - programování ve VBA." Některým věcem ovšem v té knize nerozumím. Jsem totiž samouk, a Excelu se věnuji občas po večerech, spíše to je takové hobby, že občas něco vymyslím pro sebe a kamarády (kteří ani nevědí že VBA existuje - u ních jsem King.... ), takže se případně omlouvám za to, že něco déle chápu. Chybové stavy a podobné jsem ještě neprostudoval, ještě jsem se k tomu nedostal, spíše jsem psal kod tak, aby nemohli nastat pokud to bylo možné.)
-
- Level 4
- Příspěvky: 1142
- Registrován: srpen 08
- Pohlaví:
- Stav:
Offline
Re: Obrázek do buňky v Excelu (doplnění)
Jeste ke zmene tvaru komentare v bunce Excel 2007:
Je nutno pridat na panel nastroju Rychly pristup tlacitko Zmenit tvar (Moznosti aplikace Excel>Prizpusobit>Vsechny prikazy a presunout tlacitko Zmena tvaru) a pak jiz klepnutim PT mysi na okraj komentare prejit do modu editace formatu, tl Zmena tvaru a vybrat potrebny tvar.
Je nutno pridat na panel nastroju Rychly pristup tlacitko Zmenit tvar (Moznosti aplikace Excel>Prizpusobit>Vsechny prikazy a presunout tlacitko Zmena tvaru) a pak jiz klepnutim PT mysi na okraj komentare prejit do modu editace formatu, tl Zmena tvaru a vybrat potrebny tvar.
Re: Obrázek do buňky v Excelu (doplnění)
Aha, to je super, to jsem ani nevěděl, že to tlačítko existuje....díky.
-
- Mohlo by vás zajímat
- Odpovědi
- Zobrazení
- Poslední příspěvek
-
-
Výměna / Doplnění SSD do starší sestavy
od Baski » 12 črc 2023 15:23 » v Rady s výběrem hw a sestavením PC - 2
- 678
-
od Baski
Zobrazit poslední příspěvek
12 črc 2023 17:38
-
-
-
Nejde otevřít obrázek v programu fotografie Win 10 Příloha(y)
od tuningrob » 30 led 2024 13:17 » v Windows 11, 10, 8... - 14
- 1642
-
od ITCrowd
Zobrazit poslední příspěvek
01 úno 2024 18:25
-
-
-
Excel - filtr na formát buňky + obsah Příloha(y)
od popcorn » 19 zář 2023 17:07 » v Kancelářské balíky - 0
- 2210
-
od popcorn
Zobrazit poslední příspěvek
19 zář 2023 17:07
-
-
- 18
- 3723
-
od luko02420
Zobrazit poslední příspěvek
16 kvě 2023 11:27
-
- 0
- 970
-
od Jsimi
Zobrazit poslední příspěvek
06 úno 2024 22:43
Kdo je online
Uživatelé prohlížející si toto fórum: Žádní registrovaní uživatelé a 6 hostů