Makro Word Vyřešeno

[X-Five]

Ahoj, potřeboval bych poradit, chtěl bych udělat makro ve Wordu 2010, které by mě uložilo soubor do mnou definované složky pod názvem souboru, jednou ve formátu pdf. podruhé ve formátu .docx, prostě mám soubor s názvem 1.docx, udělám v něm změny a potřebuji uložit jednou pod názvem 1.docx do např. složka1 a druhou kopii pod názvem 1.pdf do složka2. Pak mě přijde soubor 2.docx a totéž jako výše ale pod názvem 2, atd.

Lze to udělat jedním makrem, které mě to uloží pod aktuálním názvem Word souboru??
Mě se povedlo pouze, že mě to ukládá pod stejným názvem. V makrech se vůbec nevyznám, tak prosím omluvte můj prostý dotaz, díky moc za rady.

[Reklama]

[guest]

Proč si nepomůžete Záznamníkem maker (ikona ve stavovém řádku nebo karta Vývojář?)

Kód: Vybrat vše

'cesta včetně lomítka na konci
'právo do dané složky ukládat
Const cstrCesta As String = "D:\"

Sub MakroUlozit()
   
    'název dokumentu DOCX
    strCestaSouborDOCX = ActiveDocument.Name
   
    'odvozený název souboru PDF
    strCestaSouborPDF = Replace(strCestaSouborDOCX, ".docx", ".pdf")

    With ActiveDocument
   
        'DOCX
        .SaveAs FileName:=cstrCesta & strCestaSouborDOCX, _
            FileFormat:=wdFormatXMLDocument
        'PDF
       
        .ExportAsFixedFormat OutputFileName:=cstrCesta & strCestaSouborPDF, _
            ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
           
    End With

End Sub

Umístění asi přímo do šablony (Normal.dotm), na panel nástrojů Rychlý přístup (Soubor / Možnosti / Panel nástrojů rychlý přístup / Zvolit příkazy z: Makra) vložit ikonku s přiřazeným makrem.

V případě potřeby změníte cestu v deklaraci proměnné (první řádek). Teoreticky bych vás mohl nechat vybírat složku dialogem, ale přijde mi to zbytečné a zdržující. V kódu je také vypnuto zobrazení PDF po jeho vytvoření (OpenAfterExport).

[X-Five]

No to je přesně to co potřebuji, děkuji mnohokrát, je to super, jen pokud by jste byl tak moc hodný a napsal mě návod jak udělám aby mě to uložilo .docx do jedné složky (to jsem napsal do řádky Const cstrCesta As String = "D:\" a to .pdf do jiné mnou definované složky, teď to ukládá do jedné. Vím, že se ptám blbě ale jsem opravdu laik. Ale tohle mě ušetří denní rutinu, ještě jednou díky moc za ochotu a pomoc.

[cmuch]

Přidal jsem tam druhou konstantu

Kód: Vybrat vše

'cesta včetně lomítka na konci
'právo do dané složky ukládat
Const cstrCestaDOCX As String = "D:\"
Const cstrCestaPDF As String = "D:\"

Sub MakroUlozit()
   
    'název dokumentu DOCX
    strNazevSouborDOCX = ActiveDocument.Name
   
    'odvozený název souboru PDF
    strNazevSouborPDF = Replace(strNazevSouborDOCX, ".docx", ".pdf")

    With ActiveDocument
   
        'DOCX
        .SaveAs FileName:=cstrCestaDOCX & strNazevSouborDOCX, _
            FileFormat:=wdFormatXMLDocument
        'PDF
       
        .ExportAsFixedFormat OutputFileName:=cstrCestaPDF & strNazevSouborPDF, _
            ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
           
    End With

End Sub

[X-Five]

To je přesně ono, děkuji za Váš čas.